mirror of
https://github.com/mozilla/gecko-dev.git
synced 2025-11-09 21:00:42 +02:00
eaac9e2bed
Downloaded from https://pypi.python.org/packages/source/v/virtualenv/virtualenv-14.0.1.tar.gz and extracted without any modifications. This appears to speed up `mach configure` for artifact builds by ~3.3s on my Linux machine (~16.3s to 13.0s). A significant part of this appears to be newer version of pip caching and reusing wheels after first install. This should be a rubber stamp review, as all changes are from trusted upstream packages. --HG-- extra : rebase_source : a38af27ab45f21e9ea943fcd23655b3ce51ffdd8
76 lines
2.2 KiB
Fish
76 lines
2.2 KiB
Fish
# This file must be used using `. bin/activate.fish` *within a running fish ( http://fishshell.com ) session*.
|
|
# Do not run it directly.
|
|
|
|
function deactivate -d 'Exit virtualenv mode and return to the normal environment.'
|
|
# reset old environment variables
|
|
if test -n "$_OLD_VIRTUAL_PATH"
|
|
set -gx PATH $_OLD_VIRTUAL_PATH
|
|
set -e _OLD_VIRTUAL_PATH
|
|
end
|
|
|
|
if test -n "$_OLD_VIRTUAL_PYTHONHOME"
|
|
set -gx PYTHONHOME $_OLD_VIRTUAL_PYTHONHOME
|
|
set -e _OLD_VIRTUAL_PYTHONHOME
|
|
end
|
|
|
|
if test -n "$_OLD_FISH_PROMPT_OVERRIDE"
|
|
# Set an empty local `$fish_function_path` to allow the removal of `fish_prompt` using `functions -e`.
|
|
set -l fish_function_path
|
|
|
|
# Erase virtualenv's `fish_prompt` and restore the original.
|
|
functions -e fish_prompt
|
|
functions -c _old_fish_prompt fish_prompt
|
|
functions -e _old_fish_prompt
|
|
set -e _OLD_FISH_PROMPT_OVERRIDE
|
|
end
|
|
|
|
set -e VIRTUAL_ENV
|
|
|
|
if test "$argv[1]" != 'nondestructive'
|
|
# Self-destruct!
|
|
functions -e pydoc
|
|
functions -e deactivate
|
|
end
|
|
end
|
|
|
|
# Unset irrelevant variables.
|
|
deactivate nondestructive
|
|
|
|
set -gx VIRTUAL_ENV "__VIRTUAL_ENV__"
|
|
|
|
set -gx _OLD_VIRTUAL_PATH $PATH
|
|
set -gx PATH "$VIRTUAL_ENV/__BIN_NAME__" $PATH
|
|
|
|
# Unset `$PYTHONHOME` if set.
|
|
if set -q PYTHONHOME
|
|
set -gx _OLD_VIRTUAL_PYTHONHOME $PYTHONHOME
|
|
set -e PYTHONHOME
|
|
end
|
|
|
|
function pydoc
|
|
python -m pydoc $argv
|
|
end
|
|
|
|
if test -z "$VIRTUAL_ENV_DISABLE_PROMPT"
|
|
# Copy the current `fish_prompt` function as `_old_fish_prompt`.
|
|
functions -c fish_prompt _old_fish_prompt
|
|
|
|
function fish_prompt
|
|
# Save the current $status, for fish_prompts that display it.
|
|
set -l old_status $status
|
|
|
|
# Prompt override provided?
|
|
# If not, just prepend the environment name.
|
|
if test -n "__VIRTUAL_PROMPT__"
|
|
printf '%s%s' "__VIRTUAL_PROMPT__" (set_color normal)
|
|
else
|
|
printf '%s(%s%s%s) ' (set_color normal) (set_color -o white) (basename "$VIRTUAL_ENV") (set_color normal)
|
|
end
|
|
|
|
# Restore the original $status
|
|
echo "exit $old_status" | source
|
|
_old_fish_prompt
|
|
end
|
|
|
|
set -gx _OLD_FISH_PROMPT_OVERRIDE "$VIRTUAL_ENV"
|
|
end
|