mirror of
https://github.com/mozilla/gecko-dev.git
synced 2025-11-09 21:00:42 +02:00
0b4021fcad
# ignore-this-changeset Differential Revision: https://phabricator.services.mozilla.com/D17139 --HG-- extra : histedit_source : 084f340503d2e1a2d9e1753c38b2c4ee9c7819f3
73 lines
2.2 KiB
Text
73 lines
2.2 KiB
Text
/* -*- Mode: Objective-C++; tab-width: 2; indent-tabs-mode: nil; c-basic-offset: 2 -*- */
|
|
/* This Source Code Form is subject to the terms of the Mozilla Public
|
|
* License, v. 2.0. If a copy of the MPL was not distributed with this
|
|
* file, You can obtain one at http://mozilla.org/MPL/2.0/. */
|
|
|
|
#include "nsUserInfoMac.h"
|
|
#include "nsObjCExceptions.h"
|
|
#include "nsString.h"
|
|
#include "mozilla/Span.h"
|
|
|
|
#import <Cocoa/Cocoa.h>
|
|
#import <AddressBook/AddressBook.h>
|
|
|
|
NS_IMPL_ISUPPORTS(nsUserInfo, nsIUserInfo)
|
|
|
|
nsUserInfo::nsUserInfo() {}
|
|
|
|
NS_IMETHODIMP
|
|
nsUserInfo::GetFullname(nsAString& aFullname) {
|
|
NS_OBJC_BEGIN_TRY_ABORT_BLOCK_NSRESULT
|
|
|
|
CopyUTF8toUTF16(mozilla::MakeStringSpan([NSFullUserName() UTF8String]), aFullname);
|
|
return NS_OK;
|
|
|
|
NS_OBJC_END_TRY_ABORT_BLOCK_NSRESULT
|
|
}
|
|
|
|
NS_IMETHODIMP
|
|
nsUserInfo::GetUsername(nsACString& aUsername) {
|
|
NS_OBJC_BEGIN_TRY_ABORT_BLOCK_NSRESULT
|
|
|
|
aUsername.Assign([NSUserName() UTF8String]);
|
|
return NS_OK;
|
|
|
|
NS_OBJC_END_TRY_ABORT_BLOCK_NSRESULT
|
|
}
|
|
|
|
nsresult nsUserInfo::GetPrimaryEmailAddress(nsACString& aEmailAddress) {
|
|
NS_OBJC_BEGIN_TRY_ABORT_BLOCK_NSRESULT
|
|
|
|
// Try to get this user's primary email from the system addressbook's "me card"
|
|
// (if they've filled it)
|
|
ABPerson* me = [[ABAddressBook sharedAddressBook] me];
|
|
ABMultiValue* emailAddresses = [me valueForProperty:kABEmailProperty];
|
|
if ([emailAddresses count] > 0) {
|
|
// get the index of the primary email, in case there are more than one
|
|
int primaryEmailIndex = [emailAddresses indexForIdentifier:[emailAddresses primaryIdentifier]];
|
|
aEmailAddress.Assign([[emailAddresses valueAtIndex:primaryEmailIndex] UTF8String]);
|
|
return NS_OK;
|
|
}
|
|
|
|
return NS_ERROR_FAILURE;
|
|
|
|
NS_OBJC_END_TRY_ABORT_BLOCK_NSRESULT
|
|
}
|
|
|
|
NS_IMETHODIMP
|
|
nsUserInfo::GetEmailAddress(nsACString& aEmailAddress) {
|
|
return GetPrimaryEmailAddress(aEmailAddress);
|
|
}
|
|
|
|
NS_IMETHODIMP
|
|
nsUserInfo::GetDomain(nsACString& aDomain) {
|
|
nsAutoCString email;
|
|
if (NS_SUCCEEDED(GetPrimaryEmailAddress(email))) {
|
|
int32_t index = email.FindChar('@');
|
|
if (index != -1) {
|
|
// chop off everything before, and including the '@'
|
|
aDomain.Assign(Substring(email, index + 1));
|
|
}
|
|
}
|
|
return NS_OK;
|
|
}
|