forked from mirrors/gecko-dev
9331b9fb07
For some reason, its value in the Google style we use is 80... except for Objective-C, where it's 100, which led to things like: https://hg.mozilla.org/mozilla-central/rev/31bf68247e6e https://hg.mozilla.org/mozilla-central/rev/64ceb33533a4. There's probably a discussion to have about whether 80 is the right limit, but since it's what's used for everything except ObjC, let's roll with it. # ignore-this-changeset Differential Revision: https://phabricator.services.mozilla.com/D187409
91 lines
2.7 KiB
Text
91 lines
2.7 KiB
Text
/* -*- Mode: c++; tab-width: 2; indent-tabs-mode: nil; -*- */
|
|
/* This Source Code Form is subject to the terms of the Mozilla Public
|
|
* License, v. 2.0. If a copy of the MPL was not distributed with this
|
|
* file, You can obtain one at http://mozilla.org/MPL/2.0/. */
|
|
|
|
#import <Cocoa/Cocoa.h>
|
|
|
|
#include "AppearanceOverride.h"
|
|
|
|
#include "mozilla/Preferences.h"
|
|
#include "mozilla/StaticPrefs_browser.h"
|
|
#include "mozilla/StaticPrefs_widget.h"
|
|
|
|
#include "nsXULAppAPI.h"
|
|
#include "SDKDeclarations.h"
|
|
|
|
static void ToolbarThemePrefChanged(const char* aPref, void* aUserInfo);
|
|
|
|
@interface MOZGlobalAppearance ()
|
|
@property NSInteger toolbarTheme;
|
|
@end
|
|
|
|
@implementation MOZGlobalAppearance
|
|
|
|
+ (MOZGlobalAppearance*)sharedInstance {
|
|
static MOZGlobalAppearance* sInstance = nil;
|
|
if (!sInstance) {
|
|
sInstance = [[MOZGlobalAppearance alloc] init];
|
|
if (XRE_IsParentProcess()) {
|
|
mozilla::Preferences::RegisterCallbackAndCall(
|
|
&ToolbarThemePrefChanged,
|
|
nsDependentCString(
|
|
mozilla::StaticPrefs::GetPrefName_browser_theme_toolbar_theme()));
|
|
}
|
|
}
|
|
return sInstance;
|
|
}
|
|
|
|
+ (NSSet*)keyPathsForValuesAffectingAppearance {
|
|
return [NSSet setWithObjects:@"toolbarTheme", nil];
|
|
}
|
|
|
|
- (NSAppearance*)appearance {
|
|
switch (self.toolbarTheme) { // Value for browser.theme.toolbar-theme pref
|
|
case 0: // Dark
|
|
return [NSAppearance appearanceNamed:NSAppearanceNameDarkAqua];
|
|
case 1: // Light
|
|
return [NSAppearance appearanceNamed:NSAppearanceNameAqua];
|
|
case 2: // System
|
|
default:
|
|
return nil; // nil means "no override".
|
|
}
|
|
}
|
|
|
|
- (void)setAppearance:(NSAppearance*)aAppearance {
|
|
// ignored
|
|
}
|
|
|
|
- (NSApplication*)_app {
|
|
return NSApp;
|
|
}
|
|
|
|
+ (NSSet*)keyPathsForValuesAffectingEffectiveAppearance {
|
|
// Automatically notify any key-value observers of our effectiveAppearance
|
|
// property whenever the pref or the NSApp's effectiveAppearance change.
|
|
return
|
|
[NSSet setWithObjects:@"toolbarTheme", @"_app.effectiveAppearance", nil];
|
|
}
|
|
|
|
- (NSAppearance*)effectiveAppearance {
|
|
switch (self.toolbarTheme) { // Value for browser.theme.toolbar-theme pref
|
|
case 0: // Dark
|
|
return [NSAppearance appearanceNamed:NSAppearanceNameDarkAqua];
|
|
case 1: // Light
|
|
return [NSAppearance appearanceNamed:NSAppearanceNameAqua];
|
|
case 2: // System
|
|
default:
|
|
// Use the NSApp effectiveAppearance. This is the system appearance.
|
|
return NSApp.effectiveAppearance;
|
|
}
|
|
}
|
|
|
|
@end
|
|
|
|
static void ToolbarThemePrefChanged(const char* aPref, void* aUserInfo) {
|
|
MOZ_RELEASE_ASSERT(XRE_IsParentProcess());
|
|
MOZ_RELEASE_ASSERT(NS_IsMainThread());
|
|
|
|
MOZGlobalAppearance.sharedInstance.toolbarTheme =
|
|
mozilla::StaticPrefs::browser_theme_toolbar_theme();
|
|
}
|